SDF User Contributed Tutorials

# jgw's ~/.tcshrc, created Mon Mar 17 22:42:52 PDT 2008
 
#tcsh .tcshrc file
 
alias c		clear
alias l		ls-F
alias ls        'colorls -G'
alias la	ls -a
alias ll	ls -lA
alias d		'ls-F | grep "/"'
alias h		history 25
alias j		jobs -l
alias cm        'frm -s new'
alias sc	screen
alias fyi	'more fyi.txt'	
alias lock	'lock -np'
alias lyx	'lynx -book'
alias Mailx	'/usr/pkg/bin/mailx'
 
# alias list for nail(1)
alias na        "grep ^alias ~/.nailrc | sed 's/^alias //'"
 
# special "one dir in" recursive listing of "."
alias l1       "ls -AF `ls -A`"
 
# Stuff specifically for SDF:
alias yup       'yuptime `hosts && hostname`'
alias yho       'ywho `hosts && hostname`'
alias pgrep     'pgrep -U jgw'
alias pkill     'pkill -U jgw'
setenv  TZ      PST8EDT         # This offsets UTC to PST (8hrs diff)
setenv  MANPATH /sys/share/man:/sys/pkg/man:/usr/pkg/X11R6/man:/sys/sdf/man:${HOME}/man
setenv  SPELL   '/usr/pkg/bin/ispell -a'
 
# special tcsh aliases:
# helpcommand => evoke with <cmd>Meta+H
alias helpcommand	'man -h '
 
setenv	MAIL	/var/mail/$USER
setenv	EDITOR	vi
setenv	VISUAL	${EDITOR}
setenv	EXINIT	'set autoindent'
#setenv	PAGER	more
setenv	LS_COLORS  '*.c=31:*.mp3=32'
#setenv	CVSROOT	'anoncvs@anoncvs.NetBSD.org:/cvsroot'
# ensure nvi actually reads the ~/.nexrc file
setenv  EXINIT  'source $HOME/.nexrc'
# set alternate socket (ie temp) directory for the screen program:
setenv SCREENDIR $HOME/.screen
 
set path = (~/bin /{,s}bin /usr/{bin,sbin,X11R6/bin,pkg/{,s}bin,games} /sys/sdf/bin)
 
if ($?prompt) then
	# Got an interactive shell -- set some stuff up
	set autologout = -1
	complete cd 'p/1/d/'
	stty erase '^?'
	set filec
	set implicitcd = verbose
	set history = 1000
	set ignoreeof
	set nobeep
	set mail = (5 /var/mail/$USER)
	set autolist = ambiguous
	set colorcat
	set color
	# special prompt for use w/ screen(1)
	set prompt = "%{\ek\e\\%} %t %n@%m (\!) %# "
	#set prompt = "%t %n@%m (\!) %# "
endif